''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' ColorSpectrum.BAS			Copyright (C) Golden Software Inc. 1992-2004
'
' This sample demonstrates how to change color spectrums
'
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''

Sub main
   Dim MapViewerApp, doc, LayersObj, HatchMap, cm As Object
   Dim path As String

   'Creates an instance of the MapViewer Application object
   ' and assigns it to the variable named "MapViewerApp"
   Set MapViewerApp = CreateObject("MapViewer.Application")

   'Makes the application main window visible
   MapViewerApp.Visible = True

   'Assigns the location of the samples folder to the variable "InPath"
   path = MapViewerApp.ApplicationFolder + "samples\"

   'Creates a map document object, and assigns it to the variable named "doc"
   Set doc = MapViewerApp.Documents.Add(DocType:=mvDocPlot)

   'Assigns the layer object to the variable named "LayersObj"
   Set LayersObj = doc.Layers

   'Creates a hatch map object and assigns it to the variable named "HatchMap"
   Set HatchMap = doc.CreateHatchMap(path + "co2000.gsb", path + "co2000.dat", "", "", 1, 5, 5)

   'Assigns the foreground color spectrum object to the variable named "cm"
   Set cm = HatchMap.FgColorSpectrum

   'Changes the color spectrum to one of the items stored in the list.
   'This automatically updates the map.
   cm.LoadFromList("Flame")

   'Creats a list of color node positions and color values.
   NodePosVariant = Array(0#, 0.25, 0.5, 0.75, 1#)
   NodeColorVariant = Array(mvColorRed, mvColorGreen, mvColorBlue, mvColorRed, mvColorBlack)
   Dim np(0 To 4) As Double, nc(0 To 4) As Long
   For i = 0 To 4
      np(i) = NodePosVariant(i)
      nc(i) = NodeColorVariant(i)
   Next

   'Updates the color spectrum by assigning the new color node positions and color values.
   'This automatically updates the map.
   cm.SetNodes np, nc

End Sub